update system

modules/nixos/hardware/astro-a50-harman.txt

@@ -0,0 +1,11 @@
+Preamp: -4.08 dB
+Filter 1: ON LSC Fc 105.0 Hz Gain 3.9 dB Q 0.70
+Filter 2: ON PK Fc 51.8 Hz Gain -4.3 dB Q 0.81
+Filter 3: ON PK Fc 1118.3 Hz Gain -2.5 dB Q 3.36
+Filter 4: ON PK Fc 2620.0 Hz Gain -0.9 dB Q 3.24
+Filter 5: ON PK Fc 3300.0 Hz Gain 0.9 dB Q 5.82
+Filter 6: ON PK Fc 3859.3 Hz Gain 4.1 dB Q 3.08
+Filter 7: ON PK Fc 5115.7 Hz Gain 0.8 dB Q 5.14
+Filter 8: ON PK Fc 6116.7 Hz Gain -3.4 dB Q 3.42
+Filter 9: ON PK Fc 7416.1 Hz Gain -0.8 dB Q 4.16
+Filter 10: ON HSC Fc 10000.0 Hz Gain 0.3 dB Q 0.70

modules/nixos/hardware/astro-a50.nix

@@ -0,0 +1,73 @@
+{
+  lib,
+  config,
+  username,
+  pkgs,
+  ...
+}:
+with lib;
+
+let
+  cfg = config.hardware.astro-a50;
+in
+{
+  options.hardware.astro-a50 = {
+    enable = mkEnableOption "Enable optimisations for the Logitech Astro A50 headset";
+  };
+
+  config = mkIf cfg.enable {
+    home-manager.users.${username} =
+      let
+        name = "Astro A50";
+        nick = "A50";
+        filter = bitrate: {
+          "media.class" = "Audio/Sink";
+          "alsa.components" = "USB046d:0b1c";
+          "alsa.resolution_bits" = bitrate;
+        };
+        nodeNameIn = "astro-a50-eq-harman-in";
+      in
+      {
+        home.packages = with pkgs; [ zam-plugins ];
+        xdg.configFile = {
+          "wireplumber/wireplumber.conf.d/51-astro-a50.conf".text = builtins.toJSON {
+            "monitor.alsa.rules" = [
+              {
+                matches = [ (filter 16) ];
+                actions.update-props = {
+                  "node.description" = "${name} Chat";
+                  "node.nick" = "${nick} Chat";
+                };
+              }
+              {
+                matches = [ (filter 24) ];
+                actions.update-props = {
+                  "node.description" = name;
+                  "node.nick" = nick;
+                };
+              }
+            ];
+          };
+          "pipewire/pipewire.conf.d/51-a50-eq.conf".text = builtins.toJSON {
+            "context.modules" = [
+              {
+                name = "libpipewire-module-parametric-equalizer";
+                args = {
+                  "equalizer.filepath" = builtins.toString ./astro-a50-harman.txt;
+                  "equalizer.description" = "${name} (Harman EQ)";
+                  "capture.props" = {
+                    "node.name" = nodeNameIn;
+                    "filter.smart" = true;
+                    "filter.smart.target" = filter 24;
+                  };
+                  "playback.props" = {
+                    "node.name" = "EQ Output";
+                  };
+                };
+              }
+            ];
+          };
+        };
+      };
+  };
+}