Update Gradle to 6.7.1

Use kts build script
Update dependencies

.gitignore

@@ -3,4 +3,5 @@ admin.json
 service_channels.json
 *.hprof
 /build
-/.gradle
+/.gradle
+.idea

build.gradle

@@ -1,47 +0,0 @@
-plugins {
-    id 'org.jetbrains.kotlin.jvm' version '1.3.61'
-    id 'org.jetbrains.kotlin.plugin.serialization' version '1.3.61'
-}
-
-group 'de.wulkanat'
-version '1.4.3'
-
-repositories {
-    mavenCentral()
-    jcenter()
-}
-
-dependencies {
-    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
-
-    compile 'net.dv8tion:JDA:4.2.0_189'
-    compile 'org.jsoup:jsoup:1.13.1'
-    compile "org.jetbrains.kotlinx:kotlinx-serialization-runtime:0.14.0"
-}
-
-compileKotlin {
-    kotlinOptions.jvmTarget = "1.8"
-}
-compileTestKotlin {
-    kotlinOptions.jvmTarget = "1.8"
-}
-
-jar {
-    manifest {
-        attributes('Main-Class': 'de.wulkanat.MainKt')
-    }
-}
-
-task fatJar(type: Jar) {
-    baseName = project.name + '-all'
-    from((configurations.compile.findAll { !it.path.endsWith(".pom") }).collect {
-        it.isDirectory() ? it : zipTree(it)
-    })
-    with jar
-    manifest {
-        attributes 'Main-Class': 'de.wulkanat.MainKt',
-                'Implementation-Version': version
-    }
-}
-
-apply plugin: 'kotlinx-serialization'

build.gradle.kts

@@ -0,0 +1,61 @@
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
+
+plugins {
+    val kotlinVersion = "1.4.10"
+
+    kotlin("jvm") version kotlinVersion
+    kotlin("plugin.serialization") version kotlinVersion
+
+    id("org.jetbrains.kotlin.kapt") version kotlinVersion
+}
+
+group = "de.wulkanat"
+version = "2.0.0"
+
+repositories {
+    mavenCentral()
+    jcenter()
+    maven("https://kotlin.bintray.com/koltinx")
+    maven("https://dl.bintray.com/kordlib/Kord")
+}
+
+dependencies {
+    testImplementation(kotlin("test-junit"))
+
+    implementation("org.jetbrains.kotlin:kotlin-stdlib-jdk8")
+
+    implementation("org.jsoup:jsoup:1.13.1")
+
+    implementation("dev.kord:kord-common:0.7.0-RC")
+    implementation("com.gitlab.kordlib.kordx:kordx-commands-runtime-kord:0.3.4")
+    implementation("com.gitlab.kordlib:kordx.emoji:0.4.0")
+
+    implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.0.1")
+    implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.4.2")
+
+    kapt("com.gitlab.kordlib.kordx:kordx-commands-processor:0.3.4")
+}
+
+tasks.test {
+    useJUnit()
+}
+
+tasks.withType<KotlinCompile> {
+    kotlinOptions.jvmTarget = "1.8"
+}
+
+tasks.withType<Jar> {
+    manifest {
+        attributes(mapOf(Pair("Main-Class", "de.wulkanat.MainKt")))
+    }
+}
+
+tasks.create<Jar>("fatJar") {
+    archiveBaseName.set("${project.name}-all")
+    manifest {
+        attributes["Implementation-Version"] = archiveVersion
+        attributes["Main-Class"] = "de.wulkanat.MainKt"
+    }
+    from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
+    with(tasks.jar.get() as CopySpec)
+}

gradle/wrapper/gradle-wrapper.properties

@@ -1,6 +1,5 @@
-#Thu Aug 13 18:41:46 CEST 2020
-distributionUrl=https\://services.gradle.org/distributions/gradle-5.2.1-all.zip
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-zipStorePath=wrapper/dists
+distributionUrl=https\://services.gradle.org/distributions/gradle-6.7.1-bin.zip
 zipStoreBase=GRADLE_USER_HOME
+zipStorePath=wrapper/dists

settings.gradle

@@ -1,2 +0,0 @@
-rootProject.name = 'HytaleUpdateBot'
-

settings.gradle.kts

@@ -0,0 +1,2 @@
+rootProject.name = "HytaleUpdateBot"
+